macros.h

Go to the documentation of this file.

/* 
 * OpenVirtualization: 
 * For additional details and support contact [email protected].
 * Additional documentation can be found at www.openvirtualization.org
 * 
 * Copyright (C) 2010-2014 SierraWare
 * 
 * This library is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 * 
 * You should have received a copy of the GNU General Public License
 * along with this program; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
 * 
 */
.macro save_context
        stp             x29, x30, [sp, #-16]!
        stp             x27, x28, [sp, #-16]!
        stp             x25, x26, [sp, #-16]!
        stp             x23, x24, [sp, #-16]!
        stp             x21, x22, [sp, #-16]!
        stp             x19, x20, [sp, #-16]!
        stp             x17, x18, [sp, #-16]!
        stp             x15, x16, [sp, #-16]!
        stp             x13, x14, [sp, #-16]!
        stp             x11, x12, [sp, #-16]!
        stp             x9, x10, [sp, #-16]!
        stp             x7, x8, [sp, #-16]!
        stp             x5, x6, [sp, #-16]!
        stp             x3, x4, [sp, #-16]!
        stp             x1, x2, [sp, #-16]!
        stp             x0, x0, [sp, #-16]! // FIXME : Storing to fix sp alignment
#ifdef __KERNEL_EL1__
        mrs             x1, elr_el1
        mrs             x0, spsr_el1
        stp             x0, x1, [sp, #-16]!
#endif
#ifdef __KERNEL_EL2__
        mrs             x1, elr_el2
        mrs             x0, spsr_el2
        stp             x0, x1, [sp, #-16]!
#endif
#ifdef __KERNEL_EL3__
        mrs             x0, ttbr1_el1
        mrs             x1, sctlr_el1
        stp             x0, x1, [sp, #-16]!
        mrs             x0, vbar_el1
        mrs             x1, ttbr0_el1
        stp             x0, x1, [sp, #-16]!
        mrs             x1, spsr_el1
        mrs             x0, elr_el1
        stp             x0, x1, [sp, #-16]!
        mrs             x1, sp_el1
        mrs             x0, sp_el0
        stp             x0, x1, [sp, #-16]!
        mrs             x1, elr_el3
        mrs             x0, spsr_el3
        stp             x0, x1, [sp, #-16]!
#endif
        mov             x0, sp
.endm

.macro restore_context
        mov             sp, x0
#ifdef __KERNEL_EL3__
        ldp             x0, x1, [sp], #16
        msr             spsr_el3, x0
        msr             elr_el3, x1
        ldp             x0, x1, [sp], #16
        msr             sp_el0, x0
        msr             sp_el1, x1
        ldp             x0, x1, [sp], #16
        msr             elr_el1, x0
        msr             spsr_el1, x1
        ldp             x0, x1, [sp], #16
        msr             vbar_el1, x0
        msr             ttbr0_el1, x1
        ldp             x0, x1, [sp], #16
        msr             ttbr1_el1, x0
        msr             sctlr_el1, x1
#endif
#ifdef __KERNEL_EL2__
        ldp             x0, x1, [sp], #16
        msr             spsr_el2, x0
        msr             elr_el2, x1
#endif
#ifdef __KERNEL_EL1__
        ldp             x0, x1, [sp], #16
        msr             spsr_el1, x0
        msr             elr_el1, x1
#endif
        ldp             x1, x0, [sp], #16
        ldp             x1, x2, [sp], #16
        ldp             x3, x4, [sp], #16
        ldp             x5, x6, [sp], #16
        ldp             x7, x8, [sp], #16
        ldp             x9, x10, [sp], #16
        ldp             x11, x12, [sp], #16
        ldp             x13, x14, [sp], #16
        ldp             x15, x16, [sp], #16
        ldp             x17, x18, [sp], #16
        ldp             x19, x20, [sp], #16
        ldp             x21, x22, [sp], #16
        ldp             x23, x24, [sp], #16
        ldp             x25, x26, [sp], #16
        ldp             x27, x28, [sp], #16
        ldp             x29, x30, [sp], #16
.endm


/* TLB invalidate operations */
.macro  TLBIALL
#if defined __KERNEL_EL1__
        tlbi    vmalle1is
#elif defined __KERNEL_EL2__
        tlbi    alle2is
#elif defined __KERNEL_EL3__
        tlbi    alle3is
#endif
.endm   

.macro SET_KERN_TTBR
#if defined __KERNEL_EL1__
         bl    set_ttbr1
#else
         bl    set_ttbr0
#endif
.endm